Comment faire pour avoir un collant en-tête pour un GridLayout dans un Flickable

C'est très orthodoxe, mais j'ai trouvé une solution.

Tout d'abord, créer de "dummy" en-têtes qui sont Items. Vous pouvez faire établir leurs Layout.minimalWidth à la largeur du texte d'en-tête si vous en avez besoin.

Puis, dans un Article avant de le Flickable, créer votre propre en-tête, assurez-vous qu'il est alignée horizontalement avec la grille, et de placer les éléments à l'aide de la x les valeurs de l'en-tête.

Enfin, définissez une marge négative sur la Flickable pour supprimer le superflu ligne a été ajoutée par le mannequin en-têtes.

J'ai aussi essayé d'utiliser fillWidth: true sur les mannequins et puis en définissant la width de chaque en-tête des articles, mais l'inconvénient est qu'il modifie la largeur de colonne.

import QtQuick 2.0
import QtQuick.Layouts 1.12

ColumnLayout {
    width: 200
    height: 200

    // Header
    Item {
        Layout.minimumHeight: childrenRect.height
        Layout.fillWidth: true
        Text {
            id: header0
            x: headerDummy0.x
            anchors.top: parent.top
            text: "Header 0"
        }
        Text {
            id: header1
            x: headerDummy1.x
            anchors.top: parent.top
            text: "Header 1"
        }
        Text {
            id: header2
            x: headerDummy2.x
            anchors.top: parent.top
            text: "Header 2"
        }
    }

    Flickable {
        Layout.fillWidth: true
        Layout.preferredHeight: 200
        contentWidth: width
        contentHeight: grid.height
        clip: true
        // Eliminate the first row, which are the dummies
        topMargin: - grid.rowSpacing

        GridLayout {
            id: grid
            columns: 3
            rowSpacing: 50
            columnSpacing: 10

            function reparentChildren(source, target) {
                while (source.children.length) {
                    source.children[0].parent = target;
                }
            }

            // Header dummies
            Item {
                id: headerDummy0
                Layout.minimumWidth: header0.implicitWidth
            }
            Item {
                id: headerDummy1
                Layout.minimumWidth: header1.implicitWidth
            }
            Item {
                id: headerDummy2
                Layout.minimumWidth: header2.implicitWidth
            }

            // Data
            Repeater {
                model: 50

                Item {
                    Component.onCompleted: grid.reparentChildren(this, grid)
                    Text {
                        text: "Column 0, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 1, %1".arg(modelData)
                    }
                    Text {
                        text: "Column 2, %1".arg(modelData)
                    }
                }
            }
        }
    }
}